Excel VBA Code to Print (Save As) to PDF Multiple Pages

Sub Print_All_Sheets_To_Separate_PDF()
    'Declare variables to store the sheet name 
    Dim W_Sheets As Worksheet
    
    'Loop through all worksheets in the current workbook.
    For Each W_Sheets In ThisWorkbook.Worksheets
        'Construct the file path for the PDF file by appending the sheet name.
        'and .pdf extension to the directory path of the current workbook.
        Dim Path_of_file As String
        Path_of_file = ThisWorkbook.Path & "\" & W_Sheets.Name & ".pdf"
       
        'Export the worksheet as a PDF file using the ExportAsFixedFormat method.
        'xlTypePDF specifies the file format to export to.
        'The fileName parameter specifies the path and file name of the exported PDF file.
        W_Sheets.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=Path_of_file
    Next W_Sheets
End Sub

Sub Print_All_Sheets_To_Single_PDF()
    ' Declare variables for file name and sheet count
    Dim F_Name As String
    Dim Sheet_count As Integer

    ' Set file name and sheet count values
    F_Name = "SheetsBundle"
    Sheet_count = ThisWorkbook.Sheets.Count

    ' Declare and set up an array to hold sheet names
    Dim sheet_Array()
    ReDim sheet_Array(Sheet_count - 1) ' this is an array of length Sheet_count
    For x = 1 To Sheet_count
        sheet_Array(x - 1) = Sheets(x).Name ' add each sheet name to the array
    Next x

    ' Select all sheets in the sheet array
    Sheets(sheet_Array).Select

    ' Export the selected sheets as a PDF file with the specified file name and save location
    ActiveSheet.ExportAsFixedFormat xlTypePDF, ThisWorkbook.Path & "/" & F_Name & ".pdf", , , False

End Sub

Sub Print_Sheet_To_PDF_And_Rename()
    'Declare variables
    Dim F_Name As String
    Dim F_path As String
    Dim W_Sheets As Worksheet
    
    'Input box to enter user defined PDF file name
    F_Name = InputBox("Please Enter the PDF Name")
    
    'Display the Save As dialog box to let the user select a different location to save the PDF file.
    F_path = Application.GetSaveAsFilename(InitialFileName:=F_Name, FileFilter:="PDF Files (*.pdf), *.pdf")
    
    'If the user cancels the Save As dialog box, exit the sub.
    If F_path = "False" Then Exit Sub
    
    'Export the selected worksheet as a PDF file using the ExportAsFixedFormat method.
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
        Filename:=F_path
End Sub

Sub Print_Selected_Sheet_To_PDF()
    ' Declare a string variable to hold the available sheet names
    Dim Sheet As String
    Dim Sheet_Name As String

    ' Loop through all the worksheets in the workbook and add their names to the Sheet variable
    For Each Sh In ThisWorkbook.Worksheets
        Sheet = Sheet & Sh.Name & Chr(10)
    Next Sh

    ' Prompt the user to enter a sheet name and store the input in the x variable
    Sheet_Name = InputBox("Available sheets in this workbook" & Chr(10) & Sheet & Chr(10) & "Enter any sheet name")

    ' Select the sheet with the name entered by the user
    Sheets(Sheet_Name).Select

    ' Export the selected sheet as a PDF file with the sheet name and save location
    ActiveSheet.ExportAsFixedFormat xlTypePDF, ThisWorkbook.Path & "/" & ActiveSheet.Name & ".pdf", , , False

End Sub

Sub Print_Selected_Sheet_From_Selected_Workbook_To_PDF()
    Dim Sheet_name As String

    ' Prompt the user to select a file and store the file path in the file_name variable
    Dim file_name As Variant
    file_name = Application.GetOpenFilename("Excel Files (*.xls*), *.xls*", , "Select a file", , False)

    ' If the user cancels the file selection prompt, exit the subroutine
    If file_name = False Then Exit Sub

    ' Open the selected workbook and activate the first sheet
    Workbooks.Open (file_name)
    Worksheets(1).Activate

    ' Prompt the user to enter a sheet name and store the input in the x variable
    Sheet_name = InputBox("Enter the sheet name you want to print to PDF")

    ' Select the sheet with the name entered by the user
    Sheets(Sheet_name).Select

    ' Export the selected sheet as a PDF file with the sheet name and save location
    ActiveSheet.ExportAsFixedFormat xlTypePDF, ThisWorkbook.Path & "\" & Sheet_name & ".pdf", , , False

    ' Close the selected workbook without saving changes
    ActiveWorkbook.Close savechanges:=False

End Sub